*    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *    *
*
* program kopiruje soubory z odkud do kam, pokud v kam neexistuje soubor se stejnym stemem, takze drive naimportovany soubor, prejmenovany na "*.err" nebo "*.ok" se podruhe nekopiruje
* parametr odkud obsahuje adresar i masku jmena souboru (napr. ".\temp\20*.isdoc"), parametr kam cilovy adresar ("i:\d_gross\ediprijemky\")
*
* 2023-11-00 - na zacatku se zkusi zapsat a smazat testovaci soubor do ciloveho adresare
*            - kazdy soubor zvlast se kopiruje v try-catch, takze kdyz se nepodari zapis jednoho, ostatni muzou projit
*
*    *    *    *    *    *    *    *    *    *    *    *      #> ver. 2023-1100 <#       *    *    *    *    *    *    *    *    *    *    *    *    *
PARAMETERS odkud, kam

#DEFINE CRLF  CHR(13)+CHR(10)

vysledek = "  v.2023-1100 "

TRY 
    STRTOFILE("pokusny soubor k testu zapisovatelnosti", m.kam + "test.test")
    ERASE                                               (m.kam + "test.test")
CATCH TO aex_oErr 
    vysledek = m.vysledek + CRLF + " ERROR:nedari se zapsat " + m.kam + "test.test  " + ALLTRIM(STR(aex_oErr.ErrorNo)) + " " + aex_oErr.Message
ENDTRY 

pocet = ADIR(qqq, m.odkud)
? m.pocet
IF m.pocet > 0
    vysledek = m.vysledek + CHR(13)+CHR(10)+CHR(9)
    FOR iii = 1 TO m.pocet
        stem = JUSTSTEM(qqq(iii, 1))
        IF ADIR(qwe, m.kam + m.stem + ".*") = 0
            ? m.stem
            vysledek = m.vysledek + CRLF + m.stem + "  "
            TRY 
                COPY FILE (JUSTPATH(m.odkud) + "\" + qqq(iii, 1)) TO (m.kam + qqq(iii, 1))
                vysledek = m.vysledek  + "  ... OK"
            CATCH TO aex_oErr 
                vysledek = m.vysledek + ALLTRIM(STR(aex_oErr.ErrorNo)) + ":" + aex_oErr.Message
            ENDTRY 
        ENDIF 
    ENDFOR 
ENDIF
vysledek = m.vysledek + CRLF
