* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
*
* program uklada do souboru "davky.config" jmena souctovych davek (jako sekce - v hranatych zavorach)
* a k nim seznam davek, ze kterych se dana souctova davka sklada 
* pri spusteni nabidne jmena souctovych davek a k nim pak s predvyplnenymi fajfkami seznam davek k zaklikani.
* vyber je opet ulozen do davky.config a z vybranych davek je vytvorena souctova davka do davky.dbf
*
* 1014-08-15
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 

IF .not. FILE(m.gcdat_path + "davky.config")
    STRTOFILE(" ", m.gcdat_path + "davky.config")
ENDIF 
obsah_cfg_souboru = FILETOSTR(m.gcdat_path + "davky.config")
DEFINE POPUP vyber_davku FROM 5, 55 TITLE "Vyber davku" MARGIN RELATIVE SHADOW COLOR SCHEME 4
davka_k_souctu = ""
STORE 0 TO iii, poradi_baru
DO WHILE .T.
   iii = m.iii + 1
   pozice1 = AT("[", obsah_cfg_souboru, m.iii)
   pozice2 = AT("]", obsah_cfg_souboru, m.iii)
  
   IF BETWEEN(m.pozice1, 1, m.pozice2-1)
       davka_k_souctu = LEFT(SUBSTR(m.obsah_cfg_souboru, m.pozice1+1), m.pozice2-m.pozice1-1)

       poradi_baru = m.poradi_baru + 1
       cmd = "DEFINE BAR " + STR(m.poradi_baru, 2) + " OF vyber_davku PROMPT '" + m.davka_k_souctu + "'"
       &cmd
       LOOP 
   ELSE 
       EXIT 
   ENDIF 
ENDDO 
DEFINE BAR 998 OF vyber_davku PROMPT "-<nova davka>-"
DEFINE BAR 999 OF vyber_davku PROMPT "\-"
ON SELE POPUP vyber_davku DEACTIVATE POPUP
ACTIVATE SCREEN 
ACTIVATE POPUP vyber_davku
IF PROMPT() = "-<nova davka>-"
   davka_k_souctu = nova_davka()
ELSE 
   davka_k_souctu = PROMPT()
ENDIF 
DO secti_davky_2 WITH m.davka_k_souctu
RELEASE POPUP vyber_davku


*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   
FUNCTION nova_davka
lc_davka_k_souctu = ALLTRIM(LEFT(ALLTRIM(INPUTBOX("", "Zadej jmeno souctove davky", "")), 15))
RETURN UPPER(m.lc_davka_k_souctu)


*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   
PROCEDURE secti_davky_2 
LPARAMETERS davka_k_souctu
IF ! EMPTY(m.davka_k_souctu)
    davka_k_souctu = UPPER(m.davka_k_souctu)
    DO pozavirej WITH "seldruhy, sectene_davky, sectene_davky_1"

    SELECT DISTINCT davka as druh, .F. AS lbl WHERE davka # "__INVENTURA__  " ;
           FROM (m.gcdat_path + "davky") INTO TABLE(m.gcpri_path + "seldruhy")
    DELETE FOR "[" + ALLTRIM(druh) + "]" $ m.obsah_cfg_souboru

    davky = get_ini(m.davka_k_souctu, "seznam", "", m.gcdat_path + "davky.config")
    SCAN 
       IF ALLTRIM(druh) $ m.davky
           REPLACE lbl WITH .T.
       ENDIF 
    ENDSCAN 

    INDEX ON druh TAG druh
    IF RECCOUNT() > 0
        DO FORM sel_davky WITH m.davka_k_souctu TO ok_pressed
        IF m.ok_pressed
            davky = ""
            SELECT seldruhy
            SCAN FOR lbl
               davky = m.davky + "    " + ALLTRIM(druh)
            ENDSCAN 
            writeprivstr( m.davka_k_souctu, "seznam", " " + ALLTRIM(m.davky), m.gcdat_path + "davky.config")
        ENDIF 
    ENDIF
ENDIF 
DO pozavirej WITH "seldruhy, sectene_davky, sectene_davky_1"
