******************************************************************************
* Procedure file: ZUR_OUT.PRG
*
* zipuje textove zurnaly za posledni mesice
*     kas_path: cesta, POD niz se zurnaly nachazeji
*     zip_soubor: jmeno souboru vcetne cesty
*     pocet_mesicu: pocet minulych mesicu, ktere se posilaji (0 znamena jen aktualni), 
*                   pri vynechani se posle aktualni a do 11.dne mesice jeste minuly
*
* priklad: do zur_out WITH "i:\d_gast\d_kas\", "c:\ftp\data\zurnaly.7z", 3
*       zipuji se zurnaly za 3 mesice z adresare "i:\d_gast\d_kas\" a jeho podadresaru 
*       do souboru c:\ftp\data\zurnaly.7z"
*
* 2012-11-04: odmazavaji se stare zurnaly dosovym prikazem DEL /S
* 2012-11-16: pokud konci nazev zip_souboru ".zip", je komprimovano do formatu .zip, jinak do .7z
* 2012-12-03: na konci promenne vysledek je ..OK, aby se to nevypisovalo do romankova kontroloru
* 2013-10-13: opraveno mazani starych dvojmistnych zurnalu
* 2017-06-14: mohou se posilat i pepinovy zurnaly EET (pri zadanem ctvrtem parametru)
* 2018-09-24: pri ctvrtem parametru like "http" se poslou i zurnaly komunikace s datastorem
* 2018-11-12: opravena chyba, kdy 4. parametr byl vynechan
* 2019-08-14: 4. parametr se ignoruje, vzdycky se posilaji vsechny zurnaly vyjma starych dvojmistnych (z*RRMM*.txt)
* 2021-04-05: stare zurnaly se mazou za predposledni rok, starsi uz ne
* 2021-12-09: mazani uzaverkovych tisku starsich nez 1 mesic (jq)
*
*:*****************************************************************************
PARAMETERS kas_path, zip_soubor, pocet_mesicu, i_zurnaly_eet_zrusen

vysledek = " v.2021-04-05: "
kas_path = m.kas_path + IIF(RIGHT(m.kas_path,1)="\", "", "\")

if empty(m.zip_soubor)
   zip_soubor = m.pri_path + "zurnaly.7z"
endif
ERASE (m.zip_soubor)
if ! directory(JUSTPATH(m.zip_soubor))
   mkdir (JUSTPATH(m.zip_soubor))
ENDIF

IF empty(m.pocet_mesicu)
    pocet_mesicu = 0
ENDIF 

IF DAY(DATE()) < 11
    pocet_mesicu = m.pocet_mesicu + 1
    DO smaz_stare_zurnaly
ENDIF 

FOR ii = 0 TO m.pocet_mesicu
    naz_zur2 = "z*"                                    + SUBSTR( DTOS(GOMONTH(DATE(), -ii)), 3,4) + "*"

    vysledek = m.vysledek + " " + m.naz_zur2 + " "

    IF ".zip" $ m.zip_soubor
        cmd2 = "run " + m.gcini_path + "7za a -r -tzip " + m.zip_soubor + " " + kas_path + m.naz_zur2 + ".txt"
    ELSE
        cmd2 = "run " + m.gcini_path + "7za a -r       " + m.zip_soubor + " " + kas_path + m.naz_zur2 + ".txt"
    ENDIF 
    ?cmd2
    &cmd2
ENDFOR

vysledek = m.vysledek + " ... EXEC OK "


*:*****************************************************************************
PROCEDURE smaz_stare_zurnaly

vysledek = m.vysledek + m.crlf

***&& ctyrmistne zurnaly se smazou za PREDMINULY rok
rok = TRANSFORM(YEAR(DATE()) - 2002, "@L 99")
cmd = "run del /S /Q " + m.kas_path + "z?" + m.rok + "??.txt "
&cmd
vysledek = m.vysledek + m.cmd + m.crlf

*   *   *   mazani dvojmistnych starych zurnalu   *   *   *
ddd = DATE()
FOR ii = 1 TO 3
    ddd = GOMONTH(m.ddd, 1)
    cmd = "run del /S /Q " + m.kas_path + "zu" + TRANSFORM(MONTH(m.ddd), "@L 99") + ".txt "
    ddd = GOMONTH(m.ddd, 1)
    cmd = cmd +        " " + m.kas_path + "zu" + TRANSFORM(MONTH(m.ddd), "@L 99") + ".txt "
    &cmd
    vysledek = m.vysledek + m.cmd + m.crlf
ENDFOR 

rok = YEAR(DATE()) - 2    && smazou se za PREDMINULY rok
cmd = "run del /S /Q " + m.kas_path + "ZUEFTOK_" + TRANSFORM(m.rok, "@L 9999") + ".TXT* " + m.kas_path + "ZUEFTERR_" + TRANSFORM(m.rok, "@L 9999") + ".TXT"
&cmd

* mazani uzaverkovych tisku
ddd = GOMONTH(DATE(), - 1)    && smazou se starsi nez mesic
cmd = "run del /S /Q " + m.kas_path + "ZUZAV_" + DTOS(m.ddd) + "*.TXT"
&cmd
vysledek = m.vysledek + m.cmd + m.crlf
